现在位置首页 / 资源推荐 /正文

批处理一键转移个人文件夹(支持WIN7、WIN8、WIN10)

作者: IT小兵 | 2016年4月14日| 热度:℃ | 评论: |参与:

WIN7及以上系统更改个人文件夹位置,最简单就是在其他分区,如D盘,新建一个文件夹。再接把个人文件夹中所有项全部选中,剪切粘贴到这个文件夹。这样系统会自动把位置给改过去啦。

……………………………………………………………………

前几天,求助区有人求助更改个人文件夹位置的批处理。我经过
两天的研究、测试,写出一个批处理文件,个人认为已经比较完美了。可以方便地将原个人文件夹位置转移到新的位置!

本批处理自动提升运行权限为管理员权限,默认在D盘新建一个 Users 文件夹,从注册表中读取原来个人文件夹内的 桌面、我的文档、收藏夹、我的音乐、我的图片、我的视频、搜索、链接、联系人、保存的游戏 的位置,并转移到 Users 文件夹下,将原来的 下载 文件夹更改为D盘 Downloads 文件夹。并且原来的系统图标也会保留。

为了美观,我将新的个人文件夹设置了系统图标,并且显示为 用户。如图。

想要将个人文件夹转移到其他位置,只需要将批处理文件中以下位置中的D:\Users替换为相应的文件夹路径即可。

rem 设置个人文件夹

SET "Users=D:\Users"


忘了说一下,建议在运行前,将杀毒软件、QQ等先退出。批处理文件不要放在桌面,以及其他需要移动的位置上。以免影响转移效果。
代码:

@echo off
::---------------------------------------------------- 自动提升运行权限 ----------------------------------------------------::
>nul 2>&1 REG.exe query "HKU\S-1-5-19" || (
    ECHO SET UAC = CreateObject^("Shell.Application"^) > "%TEMP%\Getadmin.vbs"
    ECHO UAC.ShellExecute "%~f0", "%1", "", "runas", 1 >> "%TEMP%\Getadmin.vbs"
    "%TEMP%\Getadmin.vbs"
    DEL /f /q "%TEMP%\Getadmin.vbs" 2>nul
    Exit /b
)
::--------------------------------------------------------------------------------------------------------------------------::
SET "SF=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
SET "USF=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders"
rem 设置个人文件夹
SET "Users=D:\Users"
robocopy c:\Users "%Users%" /copyall
cd /d "%Users%
cmd /u /c echo IconResource=C:\Windows\system32\imageres.dll,117 >>desktop.ini
rem 移动原 桌面
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "Desktop"') do set Desktop=%%j
if /i "%Desktop%" NEQ "%Users%\Desktop" robocopy  "%Desktop%" "%Users%\Desktop" /E /COPYALL /XJ /MOVE
rem 移动原 收藏夹
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "Favorites"') do set Favorites=%%j
if /i "%Favorites%" NEQ "%Users%\Favorites" robocopy  "%Favorites%" "%Users%\Favorites" /E /COPYALL /XJ /MOVE
rem 移动原 视频
for /f "tokens=3,*" %%i in ('reg query "%SF%" /v "My Video"') do set Videos=%%j
if /i "%Videos%" NEQ "%Users%\Videos" robocopy  "%Videos%" "%Users%\Videos" /E /COPYALL /XJ /MOVE
rem 移动原 我的音乐
for /f "tokens=3,*" %%i in ('reg query "%SF%" /v "My Music"') do set Music=%%j
if /i "%Music%" NEQ "%Users%\Music" robocopy  "%Music%" "%Users%\Music" /E /COPYALL /XJ /MOVE
rem 移动原 我的图片
for /f "tokens=3,*" %%i in ('reg query "%SF%" /v "My Pictures"') do set Pictures=%%j
if /i "%Pictures%" NEQ "%Users%\Pictures" robocopy  "%Pictures%" "%Users%\Pictures" /E /COPYALL /XJ /MOVE 
rem 移动原 下载
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "{374DE290-123F-4565-9164-39C4925E467B}"') do set Downloads=%%j
if /i "%Downloads%" NEQ "D:\Downloads" robocopy  "%Downloads%" "D:\Downloads" /E /COPYALL /XJ /MOVE
rem 移动原 保存的游戏
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "{4C5C32FF-BB9D-43B0-B5B4-2D72E54EAAA4}"') do set Games=%%j
if /i "%Games%" NEQ "%Users%\Saved Games" robocopy  "%Games%" "%Users%\Saved Games" /E /COPYALL /XJ /MOVE 
rem 移动原 联系人
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "{56784854-C6CB-462B-8169-88E350ACB882}"') do set Contacts=%%j
if /i "%Contacts%" NEQ "%Users%\Contacts" robocopy  "%Contacts%" "%Users%\Contacts" /E /COPYALL /XJ /MOVE 
rem 移动原 搜索
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "{7D1D3A04-DEBB-4115-95CF-2F29DA2920DA}"') do set Searches=%%j
if /i "%Searches%" NEQ "%Users%\Searches" robocopy  "%Searches%" "%Users%\Searches" /E /COPYALL /XJ /MOVE 
rem 移动原 链接
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "{BFB9D5E0-C6A9-404C-B2B2-AE6DB6AF4968}"') do set Links=%%j
if /i "%Links%" NEQ "%Users%\Links" robocopy  "%Links%" "%Users%\Links" /E /COPYALL /XJ /MOVE 
rem 移动原 我的文档
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "Personal"') do set Documents=%%j
if /i "%Documents%" NEQ "%Users%\Documents" robocopy  "%Documents%" "%Users%\Documents" /E /COPYALL /XJ /MOVE 
rem Shell Folders
REG ADD "%SF%" /F /V "Personal" /T REG_SZ /D "%Users%\Documents"
REG ADD "%SF%" /F /V "Desktop" /T REG_SZ /D "%Users%\Desktop"
REG ADD "%SF%" /F /V "My Video" /T REG_SZ /D "%Users%\Videos"
REG ADD "%SF%" /F /V "My Pictures" /T REG_SZ /D "%Users%\Pictures"
REG ADD "%SF%" /F /V "Favorites" /T REG_SZ /D "%Users%\Favorites"
REG ADD "%SF%" /F /V "My Music" /T REG_SZ /D "%Users%\Music"
REG ADD "%SF%" /F /V "{374DE290-123F-4565-9164-39C4925E467B}" /T REG_SZ /D "D:\Downloads"
REG ADD "%SF%" /F /V "{4C5C32FF-BB9D-43B0-B5B4-2D72E54EAAA4}" /T REG_SZ /D "%Users%\Saved Games"
REG ADD "%SF%" /F /V "{56784854-C6CB-462B-8169-88E350ACB882}" /T REG_SZ /D "%Users%\Contacts"
REG ADD "%SF%" /F /V "{7D1D3A04-DEBB-4115-95CF-2F29DA2920DA}" /T REG_SZ /D "%Users%\Searches"
REG ADD "%SF%" /F /V "{BFB9D5E0-C6A9-404C-B2B2-AE6DB6AF4968}" /T REG_SZ /D "%Users%\Links"
rem User Shell Folders
REG ADD "%USF%" /F /V "Personal" /T REG_EXPAND_SZ /D "%Users%\Documents"
REG ADD "%USF%" /F /V "Desktop" /T REG_EXPAND_SZ /D "%Users%\Desktop"
REG ADD "%USF%" /F /V "My Video" /T REG_EXPAND_SZ /D "%Users%\Videos"
REG ADD "%USF%" /F /V "My Pictures" /T REG_EXPAND_SZ /D "%Users%\Pictures"
REG ADD "%USF%" /F /V "Favorites" /T REG_EXPAND_SZ /D "%Users%\Favorites"
REG ADD "%USF%" /F /V "My Music" /T REG_EXPAND_SZ /D "%Users%\Music"
REG ADD "%USF%" /F /V "Download Directory" /T REG_EXPAND_SZ /D "D:\Downloads"
REG ADD "%USF%" /F /V "{4C5C32FF-BB9D-43B0-B5B4-2D72E54EAAA4}" /T REG_EXPAND_SZ /D "%Users%\Saved Games"
REG ADD "%USF%" /F /V "{56784854-C6CB-462B-8169-88E350ACB882}" /T REG_EXPAND_SZ /D "%Users%\Contacts"
REG ADD "%USF%" /F /V "{7D1D3A04-DEBB-4115-95CF-2F29DA2920DA}" /T REG_EXPAND_SZ /D "%Users%\Searches"
REG ADD "%USF%" /F /V "{BFB9D5E0-C6A9-404C-B2B2-AE6DB6AF4968}" /T REG_EXPAND_SZ /D "%Users%\Links"
rem 重启 explorer.exe
taskkill /im explorer.exe /f
start "" explorer


描述:Win10
图片:
描述:Win7
图片:
图片:
图片:


点击阅读本文所属分类的更多文章: 资源推荐 。和高手一起交流:346717337
友荐云推荐

未注明转发、原文均为本站原创。分享本文请注明 原文链接

给您更多信息和帮助

在这里您可以找到更多:

技术交流群:346717337 Jquery插件交流

投稿:[email protected]

承接:企业网站门户/微网站/微商城/CMS系统/微信公众号运营/业务咨询

echarts教程系列
本月最热文章

微信扫一扫,徜徉悠嘻网,您的休闲乐园

微信公众号:快乐每一天

随机文章
标签

技术交流群:346717337

投稿:[email protected]

专业专注:企业网站门户/微网站/微商城/CMS系统/微信公众号运营/付费问题咨询